Como já vimos, um vetor é uma estrutura de dados, um conjunto de elementos. Assim, se desejamos ler 10 notas e armazenar nesse vetor, precisamos de uma estrutura de repetição para ler cada uma das 10 notas.

Agora, e se queremos descobrir a maior nota, a menor nota e a média da turma, como resolvemos?

Novamente nós precisamos percorrer todo o nosso conjunto de notas (o vetor) procurando pela maior nota, pela menor nota e acumulando o somatório de todas as notas para então calcular a média.

Como uma nota válida é um número real que varia pode variar entre 0 e 10, inicializamos as variáveis menor com o valor 11 e maior com o valor 0. A variável somaNotas é inicializada com zero pois vamos acumular a soma das notas.

programa{
	
	funcao inicio(){
		real maior = 0, menor = 11, media, somaNotas = 0.0, notas[10]
		inteiro i

		// Lê as notas
		para(i = 0; i < 10; i++){
			escreva("Digite a nota da posição ", i, ": ")
			leia(notas[i])
		}

		escreva("\n")
		// Imprime o vetor de notas
		para(i = 0; i < 10; i++)
			escreva(notas[i], ", ")
		escreva("\n")

		// Procura pelos elementos menor e maior e calcula o somatórios das notas
		para(i = 0; i < 10; i++){
			se(notas[i] < menor){
				menor = notas[i]
			}
			se(notas[i] > maior){
				maior = notas[i]
			}
			somaNotas += notas[i]
		}
		
		media = somaNotas / 10

		escreva("\nMenor nota: ", menor)
		escreva("\nMaior nota: ", maior)
		escreva("\nA média da turma foi: ", media, "\n\n")
	}
}