Na aula anterior vimos como imprimir os elementos das diagonais principal e secundária de uma matriz quadrada.

Hoje vamos aprender como imprimir os elementos acima da diagonal principal de uma matriz em Portugol.

Exercícios como este são excelentes para desenvolver o raciocínio lógico, uma vez que exigem reflexão. Para resolver este exercício basta perceber que todos os elementos acima da diagonal principal possuem o índice da linha menor que o índice da coluna.

programa{

	inclua biblioteca Util

	/* Aula 99: Imprimir os elementos acima da diagonal principal de uma matriz 6 x 6.
	 *  
	 * Escrito por Wagner Gaspar
	 * Março de 2021
	 */

	funcao inicio(){

		inteiro l, c, mat[6][6]

		para(l = 0; l < 6; l++){
			para(c = 0; c < 6; c++){
				mat[l][c] = Util.sorteia(10, 99)
			}
		}

		para(l = 0; l < 6; l++){
			para(c = 0; c < 6; c++){
				escreva(mat[l][c], " ")
			}
			escreva("\n")
		}

		escreva("\nElementos acima da diagonal principal\n")
		para(l = 0; l < 6; l++){
			para(c = 0; c < 6; c++){
				se(c > l)
					escreva(mat[l][c], " ")
				senao
					escreva("   ")
			}
			escreva("\n")
		}
		escreva("\n")
	}
}