Nas aulas anteriores nós aprendemos como escrever dados em um arquivo texto . Nesta aula veremos como ler os dados de um arquivo texto.

A função de leitura lê e retorna uma linha do arquivo. Dessa forma você precisa ficar atento ao modo como está escrevendo no arquivo, pois isso pode dificultar a leitura e separação dos dados.

Como dito, a função de leitura recebe o endereço do arquivo onde será lido e retorna a linha lida, assim:

		// lendo uma linha no arquivo
		linha = a.ler_linha(arquivo)

Caso não seja possível ler uma linha no arquivo informado, será retornado uma cadeia vazia. Isso pode ser testando com uma instrução se, assim:

		// testando se conseguiu ler
		se(linha != ""){
			escreva("linha ", n, ": ", linha, "\n")
			n++
		}

Também é possível verificar se o fim do arquivo foi atingindo, assim:

		// testando fim do arquivo
		enquanto( nao a.fim_arquivo(arquivo)){
			// enquanto não for o fim do arquivo, leia...
		}

Código completo em Portugol para ler um arquivo texto.

programa{

	inclua biblioteca Arquivos --> a

/*
	Código escrito por Wagner Gaspar
	Abril de 2021
*/
	
	funcao inicio(){

		inteiro n = 1
		inteiro arquivo = a.abrir_arquivo("./teste.txt", a.MODO_LEITURA)
		cadeia linha

		enquanto( nao a.fim_arquivo(arquivo)){
			linha = a.ler_linha(arquivo)
			se(linha != ""){
				escreva("linha ", n, ": ", linha, "\n")
				n++
			}
		}
		
		a.fechar_arquivo(arquivo)
	}
}