Nesta aula vamos iniciar nosso aprendizado sobre as estruturas de dados homogêneas. Hoje vamos começar com a estrutura vetor também chamada de array unidimensional.

Todos os programas que fizemos até agora utilizavam poucas variáveis e tinha uma relação direta entre as variáveis criadas e a quantidade de dados manipulados pelo nosso programa.

A partir dessa aula aprenderemos como trabalhar com conjuntos de dados em portugol. Se desejamos, por exemplo, calcular a média das notas de uma turma com 35 alunos, podemos criar uma variável que tenha 35 caixinhas na memória, uma para cada nota.

Variáveis desse tipo recebem um nome especial, vetor, ou ainda, array unidimensional. Unidimensional por possuir apenas uma dimensão, ou seja, pode ser representada como uma linha ou uma coluna.

Ao criar duas variáveis do tipo inteiro, por exemplo, estas variáveis podem ser criadas em qualquer parte da memória, ou seja, não existe nenhuma relação entre elas. Ao criar um vetor, por exemplo de tamanho 35, essas 35 caixinhas de memória são sequenciais, ou seja, estão uma ao lado da outra, sempre.

A criação de vetores é bem semelhante à criação de variáveis. Para criar uma variável do tipo inteiro precisamos dizer o tipo e, em seguida, dar um identificador a nossa variável, um nome, assim:

inteiro nota

Para criar um vetor seguimos os mesmos passos. Contudo, como um vetor é um conjunto de elementos do mesmo tipo, além do tipo e do identificador, precisamos indicar também a capacidade desse vetor, ou seja, quantos elementos ele pode armazenar. Isso é feito usando um par de colchetes, assim:

inteiro vetor[35]

Como preencher um vetor?

Assim como acontece quando criamos uma variável, nós não sabemos o que existe nas regiões de memória alocadas (separadas) para nossos vetores. Assim, é sempre interessante inicializar o vetor com um conjunto de valores ou pedir valores ao usuário e preencher o vetor antes de fazer qualquer operação.

Para fornecer um conjunto de valores, basta fazer uma atribuição e inserir um conjunto de valores separados por vírgula entre um par de chaves, à direita do sinal de igual, assim:

inteiro vetor[5] = {34,56,87,90,25}
real vetor2[3] = {10.5,54.2,33.8}

Como percorrer as posições de um vetor?

Como um vetor é uma estrutura sequencial na memória do computador, é simples percorrer todas as suas posições. Cada elemento possui um índice de acesso que representa sua posição no vetor, e aqui tem um detalhe extremamente importante que pode variar de linguagem para linguagem.

Na linguagem Portugol, assim como muitas linguagens de programação profissionais, o primeiro elemento do vetor SEMPRE está na posição de índice ZERO. Dessa forma, o quinto elemento, por exemplo, se encontra na posição de índice 4.

Um vetor de inteiros de tamanho 10 possui os seguintes índices:

índice: 0 1 2 3 4 5 6 7 8 9
inteiro vetor[10] = {34, 56, 67, 78, 92, 10, 23, 41, 63, 72}

Assim, concluímos que todo vetor de tamanho N possui como índices válidos a sequência de número de 0 até N – 1.

Sabendo disso, podemos então montar uma estrutura de repetição para percorrer um vetor imprimindo seu conteúdo na tela, assim:

programa{
	
	funcao inicio(){
		inteiro indice, vetIdade[5] = {16,25,32,45,87}
		real notas[5] = {4.5,5.8,8.3,9.2,10.0}
		caracter sexo[4] = {'f','F','m','M'}

		escreva("Idades: ")
		// imprime o vetor vetIdades
		para(indice = 0; indice < 5; indice++)
			escreva(vetIdade[indice], ", ")

		escreva("\n\nNotas: ")
		// imprime o vetor notas
		para(indice = 0; indice < 5; indice++)
			escreva(notas[indice], ", ")

		escreva("\n\nVetor sexo: ")
		// imprime o vetor sexo
		para(indice = 0; indice < 4; indice++)
			escreva(sexo[indice], ", ")
		
	}
}